/ / Excel VBA Interactive Userform

Excel VBA Interactive Userform

A continuación veremos un programa en Excel VBA que crea un forma de usuario interactiva. El formulario de usuario que vamos a crear se ve de la siguiente manera:

Excel VBA Interactive Userform

Explicación: siempre que ingrese un valor en el cuadro de texto de ID, Excel VBA carga el registro correspondiente. Cuando hace clic en el botón Editar / Agregar, Excel VBA edita el registro en la hoja o agrega el registro cuando la ID aún no existe. El botón Borrar borra todos los cuadros de texto. El botón Cerrar cierra el formulario de usuario.

Para crear este formulario de usuario, ejecute los siguientes pasos.

1. Abra el Editor de Visual Basic. Si el Explorador de proyectos no está visible, haga clic en Ver, Explorador de proyectos.

2. Haga clic en Insertar, formulario de usuario. Si el Cuadro de herramientas no aparece automáticamente, haga clic en Ver, Cuadro de herramientas. Su pantalla debe configurarse como se muestra abajo.

Configuración de pantalla de formulario de usuario en Excel VBA

3. Agregue las etiquetas, los cuadros de texto (primero en la parte superior, el segundo debajo del primero, etc.) y los botones de comando. Una vez que se haya completado, el resultado debe ser consistente con la imagen del formulario de usuario que se mostró anteriormente. Por ejemplo, cree un control de cuadro de texto haciendo clic en TextBox en el cuadro de herramientas. A continuación, puede arrastrar un cuadro de texto en el formulario de usuario.

4. Puede cambiar los nombres y las leyendas de los controles. Los nombres se utilizan en el código de Excel VBA. Los subtítulos son aquellos que aparecen en tu pantalla. Es una buena práctica cambiar los nombres de los controles, pero no es necesario aquí porque solo tenemos algunos controles en este ejemplo. Para cambiar el título de las etiquetas, los cuadros de texto y los botones de comando, haga clic en Ver, Ventana de propiedades y haga clic en cada control.

5. Para mostrar el formulario de usuario, coloque un botón de comando en su hoja de trabajo y agregue la siguiente línea de código:

Private Sub CommandButton1_Click()

UserForm1.Show

End Sub

Ahora vamos a crear el Sub UserForm_Initialize. Cuando use el método Mostrar para el formulario de usuario, este sub se ejecutará automáticamente.

6. Abra el Editor de Visual Basic.

7. En el Explorador de proyectos, haga clic con el botón derecho en UserForm1 y luego haga clic en Ver código.

8. Elija Userform en la lista desplegable de la izquierda. Elija Inicializar de la lista desplegable de la derecha.

9. Agregue la siguiente línea de código:

Private Sub UserForm_Initialize()

TextBox1.SetFocus

End Sub

Explicación: esta línea de código establece el foco en el primer cuadro de texto ya que aquí es donde queremos comenzar cuando se carga el formulario de usuario.

Ahora hemos creado la primera parte del formulario de usuario. Aunque ya se ve limpio, no pasará nada aún cuando ingresemos un valor en el cuadro de texto de ID o cuando hagamos clic en uno de los botones de comando.

10. En el Explorador de proyectos, haga clic con el botón derecho en UserForm1 y luego haga clic en Ver código.

11. Elija TextBox1 en la lista desplegable de la izquierda. Elija Cambiar en la lista desplegable de la derecha.

12. Agregue la siguiente línea de código:

Private Sub TextBox1_Change()

GetData

End Sub

13. En el Explorador de proyectos, haga doble clic en UserForm1.

14. Haga doble clic en el botón Editar / Agregar comando.

15. Agregue la siguiente línea de código:

Private Sub CommandButton1_Click()

EditAdd

End Sub

16. Haga doble clic en el botón de comando Borrar.

17. Agregue la siguiente línea de código:

Private Sub CommandButton2_Click()

ClearForm

End Sub

Explicación: estos subs llaman a otros subs que vamos a crear en un segundo.

18. Haga doble clic en el botón de comando Cerrar.

19. Agregue la siguiente línea de código:

Private Sub CommandButton3_Click()

Unload Me

End Sub

Explicación: esta línea de código cierra el formulario de usuario.

Es hora de crear los subs. Puede consultar nuestro Capítulo de funciones y subcapítulos para obtener más información sobre los subs. Si tiene prisa, simplemente coloque los siguientes subs en un módulo (en el Editor de Visual Basic, haga clic en Insertar, Módulo).

20. Primero, declare tres variables de tipo Integer y una variable de tipo Boolean. Declare las variables en la sección Declaraciones generales (en la parte superior del módulo). De esta manera, solo tiene que declarar las variables una vez y puede usarlas en múltiples subs.

Dim id As Integer, i As Integer, j As Integer, flag As Boolean

21. Agregue el sub GetData.

Sub GetData()

If IsNumeric(UserForm1.TextBox1.Value) Then
    flag = False
    i = 0
    id = UserForm1.TextBox1.Value

    Do While Cells(i + 1, 1).Value <> ""

        If Cells(i + 1, 1).Value = id Then
            flag = True
            For j = 2 To 3
                UserForm1.Controls("TextBox" & j).Value = Cells(i + 1, j).Value
            Next j
        End If

        i = i + 1

    Loop

    If flag = False Then
        For j = 2 To 3
            UserForm1.Controls("TextBox" & j).Value = ""
        Next j
    End If

Else
    ClearForm
End If

End Sub

Explicación: Si el cuadro de texto de ID contiene un valor numérico, Excel VBA busca el ID y carga el registro correspondiente. Usamos la colección de controles para recorrer fácilmente los cuadros de texto. Si Excel VBA no puede encontrar el ID (el indicador sigue siendo Falso), vacía el segundo y tercer cuadro de texto. Si el cuadro de texto de ID no contiene un valor numérico, Excel VBA llama al sub ClearForm.

22. Agregue el sub ClearForm.

Sub ClearForm()

For j = 1 To 3
    UserForm1.Controls("TextBox" & j).Value = ""
Next j

End Sub

Explicación: Excel VBA borra todos los cuadros de texto.

23. Añadir el sub EditAdd.

Sub EditAdd()

Dim emptyRow As Long

If UserForm1.TextBox1.Value <> "" Then
    flag = False
    i = 0
    id = UserForm1.TextBox1.Value
    emptyRow = WorksheetFunction.CountA(Range("A:A")) + 1

    Do While Cells(i + 1, 1).Value <> ""

        If Cells(i + 1, 1).Value = id Then
            flag = True
            For j = 2 To 3
                Cells(i + 1, j).Value = UserForm1.Controls("TextBox" & j).Value
            Next j
        End If

        i = i + 1

    Loop

    If flag = False Then
        For j = 1 To 3
            Cells(emptyRow, j).Value = UserForm1.Controls("TextBox" & j).Value
        Next j
    End If

End If

End Sub

Explicación: Si el cuadro de texto de ID no está vacío, Excel VBA edita el registro en la hoja (lo contrario de cargar un registro como hemos visto anteriormente). Si Excel VBA no puede encontrar el ID (el indicador sigue siendo Falso), agrega el registro a la siguiente fila vacía. La variable emptyRow es la primera fila vacía y aumenta cada vez que se agrega un registro.

24. Salga del Editor de Visual Basic, ingrese las etiquetas que se muestran a continuación en la fila 1 y pruebe el formulario de usuario.

Excel VBA Interactive Userform

Lea también: