הלוואה מחשבון ב - VBA של

דף זה מלמד אותך כיצד ליצור פשוט להלוות מחשבון in Excel VBA. גליון העבודה מכיל את פקדי ה- ActiveX הבאים: שני לחצני גלילה ושני לחצני אפשרויות.

הערה: ההוראות שלהלן אינן מלמדות כיצד לעצב את גליון העבודה. אנו מניחים שאתה יודע כיצד לשנות סוגי גופן, להוסיף שורות ועמודות, להוסיף גבולות, לשנות צבעי רקע וכו '.

בצע את השלבים הבאים כדי ליצור את מחשבון ההלוואה:

.1 הוסף את שני פקדי סרגל הגלילה. לחץ על הוספה מתוך הכרטיסייה מפתח ולאחר מכן לחץ על סרגל גלילה במקטע פקדי ActiveX.

.2 הוסף את שני לחצני האפשרויות. לחץ על הוספה מתוך הכרטיסייה מפתח ולאחר מכן לחץ על לחצן אפשרות בקטע פקדי ActiveX.

שנה את המאפיינים הבאים של פקדי הגלילה (ודא שמצב העיצוב נבחר).

3. לחץ באמצעות לחצן העכבר הימני על סרגל הגלילה הראשון ולאחר מכן לחץ על מאפיינים. הגדר מינימום ל -0, מקס ל -20, שינוי קטן ל -0 ו- LargeChange ל- 2.

4. לחץ באמצעות לחצן העכבר הימני על פקד הגלילה השני ולאחר מכן לחץ על מאפיינים. הגדר מינימום ל 5, מקס עד 30, שינוי קטן ל 1, שינוי גדול ל 5, ו- LinkedCell ל F8.

הסבר: כאשר אתה לוחץ על החץ, הערך של סרגל הגלילה עולה או יורד על ידי SmallChange. כאשר אתה לוחץ בין המחוון לבין החץ, הערך של סרגל הגלילה עולה או יורד על-ידי LargeChange.

יצירת אירוע גליון עבודה. הקוד שנוסף לאירוע שינוי גליון העבודה יבוצע על-ידי Excel VBA בעת שינוי תא בגליון עבודה.

5. פתח את עורך Visual Basic.

6. לחץ לחיצה כפולה על גיליון 1 (גיליון 1) בסייר הפרויקט.

7. בחר באפשרות גיליון עבודה מהרשימה הנפתחת שמאלה ובחר באפשרות שנה מהרשימה הנפתחת.

8. אירוע שינוי גליון העבודה מקשיב לכל השינויים ב- Sheet1. אנחנו רק רוצים Excel VBA להפעיל את תת לחשב אם משהו משתנה בתא D4. כדי להשיג זאת, הוסף את שורת הקוד הבאה לאירוע שינוי גליון העבודה (עוד על החישוב משנה בהמשך).

If Target.Address = "$D$4" Then Application.Run "Calculate"

9. קבל את הזכות אחוז בתא F6 (לשנות את הפורמט של התא F6 לאחוז). לחץ באמצעות לחצן העכבר הימני על סרגל הגלילה הראשון ולאחר מכן לחץ על View Code. הוסף את שורות הקוד הבאות:

Private Sub ScrollBar1_Change()

Range("F6").Value = ScrollBar1.Value / 100
Application.Run "Calculate"

End Sub

10. לחץ באמצעות לחצן העכבר הימני על פקד הגלילה השני ולאחר מכן לחץ על View Code. הוסף את שורת הקוד הבאה:

Private Sub ScrollBar2_Change()

Application.Run "Calculate"

End Sub

11. לחץ באמצעות לחצן העכבר הימני על לחצן בקרת האפשרות הראשון ולאחר מכן לחץ על הצג קוד. הוסף את שורת הקוד הבאה:

Private Sub OptionButton1_Click()

If OptionButton1.Value = True Then Range("C12").Value = "Monthly Payment"
Application.Run "Calculate"

End Sub

12. לחץ על לחצן העכבר הימני על לחצן הבקרה השני אפשרות, ולאחר מכן לחץ על View Code. הוסף את שורת הקוד הבאה:

Private Sub OptionButton2_Click()

If OptionButton2.Value = True Then Range("C12").Value = "Yearly Payment"
Application.Run "Calculate"

End Sub

13. הזמן ליצור את תת. אתה יכול לעבור את הפרק שלנו ואת הפרק הבא כדי ללמוד עוד על תת. אם אתה ממהר, פשוט מקום תת בשם לחשב לתוך מודול (בעורך Visual Basic, לחץ על הוסף, מודול).

Sub Calculate()

Dim loan As Long, rate As Double, nper As Integer

loan = Range("D4").Value
rate = Range("F6").Value
nper = Range("F8").Value

If Sheet1.OptionButton1.Value = True Then
rate = rate / 12
nper = nper * 12
End If

Range("D12").Value = -1 * WorksheetFunction.Pmt(rate, nper, loan)

End Sub

הסבר: המשנה מקבל את הפרמטרים הנכונים עבור פונקציית גליון העבודה Pmt. הפונקציה Pmt ב- Excel מחשבת את התשלומים עבור הלוואה על בסיס תשלומים קבועים וריבית קבועה. אם אתה מבצע תשלומים חודשיים (Sheet1.OptionButton1.Value = True), Excel VBA משתמש שיעור / 12 עבור שיעור nper * 12 עבור nper (סך כל התשלומים). התוצאה היא מספר שלילי, מכיוון שהתשלומים נחשבים לחיוב. הכפלת התוצאה על ידי -1 נותנת תוצאה חיובית.