/ / Valūtas konvertētājs programmā Excel VBA

Valūtas konvertētājs programmā Excel VBA

Tālāk mēs apskatīsim programmu programmā Excel VBA kas rada Userform, ka pārvērš jebkura summa no viena valūta citā.

Lietotāja forma, kuru mēs veidosim, izskatās šādi:

Valūtas konvertētājs programmā Excel VBA

Lai izveidotu šo Userform, izpildiet šādas darbības.

1. Atveriet Visual Basic Editor. Ja Project Explorer nav redzams, noklikšķiniet uz Skatīt, Project Explorer.

2. Noklikšķiniet uz Ielikt, Lietotāja forma. Ja rīkjosla neparādās automātiski, noklikšķiniet uz Skatīt, rīkjoslu. Jūsu ekrāns ir jāiestata tā, kā parādīts zemāk.

Userform ekrāna iestatīšana programmā Excel VBA

3 Pievienojiet etiķetes, saraksta lodziņus (pirmie pa kreisi, otro labajā pusē), teksta laukus (pirmais pa kreisi, otro labajā pusē) un komandu pogu. Kad tas ir pabeigts, rezultātam jāatbilst iepriekš redzamā lietotāja formas attēlam. Piemēram, izveidojiet saraksta lodziņa vadību, noklikšķinot uz saraksta lodziņa no rīkjoslas. Tālāk jūs varat vilkt saraksta lodziņu Userform.

4 Jūs varat mainīt vadības ierīču nosaukumus un parakstus. Vārdi tiek izmantoti Excel VBA kodā. Paraksti ir tie, kas tiek parādīti ekrānā. Laba prakse ir mainīt kontroles nosaukumus, taču šeit tas nav nepieciešams, jo šajā piemērā ir tikai dažas kontroles. Lai mainītu Userform, komandu pogas un iezīmju nosaukumu, noklikšķiniet uz Skatīt, rekvizītu loga un noklikšķiniet uz katras vadības pogas.

5. Lai parādītu Userform, ievietojiet komandas pogu savā darblapā un pievienojiet šādu koda rindiņu:

Private Sub CommandButton1_Click()

UserForm1.Show

End Sub

Tagad mēs izveidosim Sub UserForm_Initialize. Ja izmantojat Userform formātu Show method, šī apakšdaļa tiks automātiski izpildīta.

6. Atveriet Visual Basic Editor.

7. Projekta programmā labo pogu noklikšķiniet uz UserForm1 un pēc tam noklikšķiniet uz Skatīt kodu.

8. Izvēlieties Userform no kreisā nolaižamā saraksta. Izvēlieties Inicializēt labajā nolaižamajā sarakstā.

9. Pievienojiet šādas koda līnijas:

Private Sub UserForm_Initialize()

With ListBox1
    .AddItem "Euro"
    .AddItem "Us Dollar"
    .AddItem "British Pound"
End With

With ListBox2
    .AddItem "Euro"
    .AddItem "Us Dollar"
    .AddItem "British Pound"
End With

ListBox1.ListIndex = 1
ListBox2.ListIndex = 0

TextBox1.Value = 1
TextBox2.Value = 0.722152

End Sub

Paskaidrojums: pirmkārt, abas saraksta kastes ir aizpildītas. Tālāk ASV dolāra valūta ir iestatīta kā noklusējums pirmajā saraksta lodziņā, otrajā saraksta lodziņā EURO valūta ir iestatīta kā noklusējums. Visbeidzot, vērtība 1 tiek ievadīta pirmajā teksta lodziņā, un otrajā tekstlodziņā tiek ievadīta vērtība 0.722152.

Tagad mēs esam izveidojuši lietotāja formas pirmo daļu. Lai gan tas izskatās pievilcīgs jau, nekas nenotiks, kad mēs noklikšķināsim uz pogas "Uz priekšu".

10. Projekta Explorer divreiz noklikšķiniet uz UserForm1.

11. Divreiz nospiediet pogu Go.

12. Pievienojiet šādas koda līnijas:

Private Sub CommandButton1_Click()

Dim rates(0 To 2, 0 To 2) As Double, i As Integer, j As Integer

rates(0, 0) = 1
rates(0, 1) = 1.38475
rates(0, 2) = 0.87452

rates(1, 0) = 0.722152
rates(1, 1) = 1
rates(1, 2) = 0.63161

rates(2, 0) = 1.143484
rates(2, 1) = 1.583255
rates(2, 2) = 1

For i = 0 To 2
    For j = 0 To 2
        If ListBox1.ListIndex = i And ListBox2.ListIndex = j Then TextBox2.Value = TextBox1.Value * rates(i, j)
    Next j
Next i

End Sub

Paskaidrojums: vispirms mēs deklarējam masīvu. Masīvam ir divas dimensijas. To veido 3 rindas un 3 kolonnas. Tālāk mēs inicializējam katru elementa masīvu. Piemēram, likmes (1,0) ir valūtas kurss no ASV dolāra uz EURO. Tālāk mēs sākam dubultu cilpu. Atkarībā no izvēlētajām valūtām saraksta lodziņos Excel VBA pārveido summu, kas ievadīta pirmajā teksta lodziņā, un parādīs rezultātu otrajā tekstlodziņā.

Piemērs: ja i = 2 un j = 1 un mēs pirmajā tekstlodziņā ievadām vērtību 2, Excel VBA ievieto otrajā tekstlodziņā vērtību 2 * likmes (2,1) = 2 * 1,583255 = 3,16651.

13. Pārbaudiet Userform.

Rezultāts:

Valūtas konvertēšanas rezultāts

Lasīt arī: